;*****************************************************************************
;***** FICHIER		: BOOTLD10.ASM
;***** VERSION		: 1.0
;***** DESCRIPTION	: Bios pour téléchargement logiciel en flash depuis PC
;***** PCB			: Toute carte à base de PIC 16f876 ou 18F877 avec liaison RS232
;***** AUTEUR		: G. B
;***** DATE			: 08/2007
;*****
;***** Modifications par rapport a la version precedente :
;*****
;***** Bugs connus :
;*****
;*****************************************************************************

;*****************************************************************************
;                      Paramétrage de la compilation                         *
;*****************************************************************************
	LIST      p=16F877a			; Définition de processeur

	variable	CLCK_SPEED=20	; Définit la freq du quartz en MHz. Permet aux tempos et timers de s'adapter
								; Valeurs prevues : 4 ou 20 MHz

	#include <p16F877a.inc>		; fichier include
	#include <macros10.inc>		; Macros utiles


	__CONFIG   _CP_OFF & _DEBUG_OFF & _WRT_OFF & _CPD_OFF & _LVP_OFF & _BODEN_OFF & _PWRTE_OFF & _WDT_OFF & _HS_OSC
			;_CP_ALL			protection Flash totale
			;_CP_OFF			Pas de protection Flash
			;_DEBUG_ON			RB6 et RB7 utilisées pour debugger
			;_DEBUG_OFF			RB6 et RB7 en utilisation normale
			;_WRT_OFF			No prog memory write protection
			;_WRT_256			First 256 prog memory write protected
			;_WRT_1FOURTH		First quarter prog memory write protected
			;_WRT_HALF			First half memory write protected
			;_CPD_ON			Mémoire EEprom protégée
			;_CPD_OFF			Mémoire EEprom déprotégée
			;_LVP_ON			RB3 permet la programmation série de la PIC
			;_LVP_OFF			RB3 en utilisation normale
			; _BODEN_ON			Reset si Vdd < 4V. Valide PWRTE_ON automatiquement
			; _BODEN_OFF		Reset tension hors service
			;_PWRTE_OFF			Démarrage rapide
			;_PWRTE_ON			Démarrage temporisé
			;_WDT_ON			Watchdog en service
			;_WDT_OFF			Watchdog hors service
			;_LP_OSC			Oscillateur basse vitesse (32<F<200Khz)
			;_XT_OSC			Oscilateur moyenne vitesse (200Khz<F<4Mhz)
			;_HS_OSC			Oscillateur haute vitesse (4Mhz<F<20Mhz)
			;_RC_OSC			Oscillateur à réseau RC

	variable	VERBOSE=1				; Activation des envois de commentaires sur la liaison série
	variable	ADR_Appli=0x1F00		; Adresse de l'application
	variable	ADR_BootLoader=0x1F04	; Adresse du BootLoader
	variable	ADR_Max=0x1FFF			; Adresse Max du processeur

;*****************************************************************************
;                      Configuration système                                 *
;*****************************************************************************

OPTIONVAL	EQU	B'00000000'	; ---- REGISTRE OPTION_REG (configuration)
			; RBPU		b7 : 1= Résistance rappel +5V hors service
			; INTEDG	b6 : 1= Interrupt sur flanc montant de RB0
			;				 0= Interrupt sur flanc descend. de RB0
			; TOCS		b5 : 1= source clock = transition sur RA4
			;				 0= horloge interne
			; TOSE		b4 : 1= Sélection flanc montant RA4(si B5=1)
			;				 0= Sélection flanc descendant RA4
			; PSA		b3 : 1= Assignation prédiviseur sur Watchdog
			;				 0= Assignation prédiviseur sur Tmr0
			; PS2/PS0	b2/b0 valeur du prédiviseur
            ;						(watchdog)	   (tmr0)
            ;				000 =  		1/1			1/2
			;				001 =  		1/2			1/4
			;				010 =  		1/4			1/8
			;				011 =		1/8			1/16
			;				100 =  		1/16		1/32
			;				101 =  		1/32		1/64
			;				110 =  		1/64		1/128
			;				111 =  		1/128		1/256

;INTCONVAL	EQU	B'01000000'	; ---- REGISTRE INTCON (contrôle interruptions standard)
			; GIE       b7 : masque autorisation générale interrupt
                        ;    ne pas mettre ce bit à 1 ici, sera mis en temps utile
			; PEIE      b6 : masque autorisation générale périphériques
			; T0IE      b5 : masque interruption tmr0
			; INTE      b4 : masque interuption RB0/Int
			; RBIE      b3 : masque interruption RB4/RB7
			; T0IF      b2 : flag tmr0
			; INTF      b1 : flag RB0/Int
			; RBIF      b0 : flag interruption RB4/RB7

;DIRPORTA	EQU	B'11111111'		; Direction PORTA (1=entrée)	;au power-up, tous les I/O sont des entrées par défaut
;DIRPORTB	EQU	B'11111111'		; Direction PORTB
DIRPORTC	EQU	B'10111111'		; Direction PORTC RC6 = TX

; ////////////////////////////////////////////////////////////////////////////
;                  				 V A R I A B L E S
; ////////////////////////////////////////////////////////////////////////////

	CBLOCK 0x70		;0x70 à 0x7F accessible dans toutes les banques
		V_BIOS_Ctrl :		1
		V_TRS_RxStep :		1
		V_TRS_NbChar :		1
		V_TRS_Checksum :	1
		V_BIOS_RegH :		1
		V_BIOS_RegL :		1
		V_BIOS_AdrH :		1
		V_BIOS_AdrL :		1
		V_BIOS_WriteAdrH :		1
		V_BIOS_WriteAdrL :		1
	ENDC

#define	V_BIOSMode		V_BIOS_Ctrl,0

; ////////////////////////////////////////////////////////////////////////////
;                   D E M A R R A G E   S U R   R E S E T
; ////////////////////////////////////////////////////////////////////////////

	org 0x000
	bsf		PCLATH,4
	bsf		PCLATH,3
  	goto 	Principal

; ////////////////////////////////////////////////////////////////////////////
;                           R O U T I N E S
; ////////////////////////////////////////////////////////////////////////////

;*****************************************************************************
;*********** 				Transmission serie des programmes
;*****************************************************************************

	org ADR_BootLoader
	
TRS_OpenComm		;4800 bauds --- Ne pas augmenter à cause du temps d'écriture en flash
	BANK1
	if CLCK_SPEED==20
		MOVLF	0x40, SPBRG
	else
		MOVLF	0x0C, SPBRG
	endif

	MOVLF	B'00100000', TXSTA
			; CSRC		b7 : Clock source select (inutilisé en asynchrone)
			; TX9		b6 : 9-bit transmit enable bit
			; TXEN		b5 : Transmit Enable bit
			; SYNC		b4 : USART Mode Select bit (1 = Synchronous mode, 0 = Asynchronous mode)
			; UNUSED	b3 :
			; BRGH		b2 : High Baud Rate Select bit (Asynchronous mode: 1 = High speed, 0 = Low speed)
			; TRMT		b1 : Transmit Shift Register Status bit (1 = TSR empty, 0 = TSR full)
			; TX9D		b0 : 9th bit of Transmit Data, can be parity bit

	BANK0
	MOVLF	B'10000000', RCSTA
			; SPEN		b7 : Serial Port Enable bit
			; RX9		b6 : 9-bit Receive Enable bit
			; SREN		b5 : Single Receive Enable bit (inutilisé en asynchrone)
			; CREN		b4 : Continuous Receive Enable bit (Asynchronous mode: 1 = Enables continuous receive, 0 = Disables continuous receive)
			; ADDEN		b3 : Address Detect Enable bit (inutilisé hors mode 9-bit)
			; FERR		b2 : Framing Error bit
			; OERR		b1 : Overrun Error bit
			; RX9D		b0 : 9th bit of Received Data (can be parity bit, but must be calculated by user firmware)

	clrf	PIR1				; effacer flags 1
	clrf	PIR2				; effacer flags 2
	bsf		RCSTA,CREN			; Autorise RX série
	return

;///////////////////////////////////////////////////////////////////////////////////
TRS_RxProg	; --- Gestion réception série : réception du programme à mettre en Flash
			; La trame initiale ouvre la communication :
			;		FF
			; Les trames successives sont constituees des octets suivants :
			;		N, AdrH, AdrL, Word1H, Word1L, Word2H, Word2L..., WordNH, WordNL, FF
			; La trame finale clot la communication :
			;		FF

	movf	RCREG,W						; Récupère le caractère reçu

TRP_00000001	; ---- Recuperation FF (start of transmission)
	btfss	V_TRS_RxStep,0
			goto	TRP_00000010
		bcf		STATUS,C				; Teste si caractere recu est bien FF
		addlw	0x01
		btfsc	STATUS,C
				goto	TRP_Suite1
			if VERBOSE==1
				movlw	0x11		; "Incorrect start of transmission
				call	RS232_SendW
			endif
			bcf		V_BIOSMode			; Fin réception
			return
TRP_Suite1								; Passage a l'etape suivante
		btfss	PIR1,TXIF			; Attend que le buffer d'émission soit vide
			goto $-1
		MOVLF	0x01,TXREG			; "Transmission started"
		MOVLF	B'00000010', V_TRS_RxStep
	return

TRP_00000010	; ---- Recuperation nb words a recevoir ou 00 si terminé
	btfss	V_TRS_RxStep,1
			goto	TRP_00000100
		movwf	V_TRS_NbChar
		btfss	STATUS,Z				; Teste si caractere recu est 00
				goto	TRP_Suite2
			if VERBOSE==1
				movlw	0x0A			; "Transmission completed"
				call	RS232_SendW
			endif
			bcf		V_BIOSMode				; Fin réception
			return
TRP_Suite2
		bcf		STATUS,C				; Teste si caractere recu est bien différent de FF
		addlw	0x01
		btfsc	STATUS,C
				return					; Sinon, reste dans l'étape courante pour attendre l'octet suivant
		clrf	V_TRS_Checksum
		if VERBOSE==1
			movlw	0x02				; "Receiving new line …"
			call	RS232_SendW
		endif
		MOVLF	B'00000100', V_TRS_RxStep
	return

TRP_00000100	; ---- Recuperation octet poids fort de l'adresse
	btfss	V_TRS_RxStep,2
		goto	TRP_00001000
	movwf	V_BIOS_AdrH
	addwf	V_TRS_Checksum,F			; Incremente CHECKSUM
	if VERBOSE==1
		movlw	0x03				; "Receiving …"
		call	RS232_SendW
	endif
	MOVLF	B'00001000', V_TRS_RxStep
	return

TRP_00001000	; ---- Recuperation octet poids faible de l'adresse
	btfss	V_TRS_RxStep,3
		goto	TRP_00010000
	movwf	V_BIOS_AdrL
	addwf	V_TRS_Checksum,F			; Incremente CHECKSUM
	if VERBOSE==1
		movlw	0x03				; "Receiving …"
		call	RS232_SendW
	endif
	MOVLF	B'00010000', V_TRS_RxStep
	return

TRP_00010000	; ---- Recuperation Octet poids faible WordN (16 words max ?)
	btfss	V_TRS_RxStep,4
		goto	TRP_00100000
	movwf	V_BIOS_RegL
	addwf	V_TRS_Checksum,F			; Incremente CHECKSUM
	if VERBOSE==1
		movlw	0x03				; "Receiving …"
		call	RS232_SendW
	endif
	MOVLF	B'00100000', V_TRS_RxStep
	return

TRP_00100000	; ---- Recuperation Octet poids fort WordN
	btfss	V_TRS_RxStep,5
		goto	TRP_01000000
	movwf	V_BIOS_RegH
	addwf	V_TRS_Checksum,F			; Incremente CHECKSUM
	call	TranslateBootSegment		; Translate si dans la zone 0x0000h - 0x0003h
	call	FLASH_Write					; Ecriture en flash
	INCR16	V_BIOS_AdrH, V_BIOS_AdrL	; Incremente le registre 16 bits contenant l'adresse
	decfsz	V_TRS_NbChar,f				; Si c'est le dernier charactere, passage a l'etape suivante
			goto TRP_Suite62
		if VERBOSE==1
			movlw	0x04				; "Receiving checksum …"
			call	RS232_SendW
		endif
		MOVLF	B'01000000', V_TRS_RxStep
		return
TRP_Suite62								; Sinon, passage a la precedente (poids faible data suivant)
		if VERBOSE==1
			movlw	0x03				; "Receiving …"
			call	RS232_SendW
		endif
		MOVLF	B'00010000', V_TRS_RxStep
	return

TRP_01000000	; ---- Recuperation Checksum
	btfss	V_TRS_RxStep,6
		return
	subwf	V_TRS_Checksum,W			; Compare les CHECKSUM
	btfsc	STATUS,Z
			goto	TRP_Suite7
		if VERBOSE==1
			movlw	0x15				; "Checksum received and NOK"
			call	RS232_SendW
		endif
		bcf		V_BIOSMode				; Fin réception
		return
TRP_Suite7
	if VERBOSE==1
		movlw	0x05				; "Checksum received and OK"
		call	RS232_SendW
	endif
		MOVLF	B'00000010', V_TRS_RxStep
	return

;*****************************************************************************
;*********** 	Envoie W sur RS232 quand dispo
;*****************************************************************************
RS232_SendW
	btfss	PIR1,TXIF		; Attend que le buffer d'émission soit vide
		goto $-1
	movwf	TXREG			; Envoi
	return
;*****************************************************************************
;*********** 	Vérifie que l'adresse où écrire est > 0003h sinon la déplace
;*****************************************************************************
TranslateBootSegment
	; Copie l'adresse dans l'adresse d'écriture
	MOVR16ToR16 V_BIOS_AdrH, V_BIOS_AdrL, V_BIOS_WriteAdrH, V_BIOS_WriteAdrL

	; Vérifie que l'adresse est > 0003h sinon déplace
	movf    V_BIOS_WriteAdrH,W
	btfss   STATUS,Z				; AddressH = 0 ? 
		goto    TBS_Fin				; Sinon, fin
	
	movlw   0xfc
	addwf   V_BIOS_WriteAdrL,W		; W = AddressL-4
	btfsc   STATUS,C				; W < 0 ?
		goto    TBS_Fin				; Sinon, fin
	
	; Translation vers la zone ADR_Appli -> ADR_Appli + 3
	movf    V_BIOS_WriteAdrL,W		; relocate low adress
	addlw   low (ADR_Appli)			; add low address to new location
	movwf	V_BIOS_WriteAdrL
	
	MOVLF   high (ADR_Appli), V_BIOS_WriteAdrH	;get new location high address

TBS_Fin
	return

;*****************************************************************************
;*********** 				Ecriture en FLASH
;*****************************************************************************
FLASH_Write		; ---- Ecrire FLASH (adresse	= V_BIOS_AdrH:V_BIOS_AdrL,
				;					 data		= V_BIOS_RegH:V_BIOS_RegL)
	
	; Verif que AdressH <= 0x1F pour ne pas dépasser la capacité du processeur 
	movlw   (0xFF-high(ADR_Max))
	addwf   V_BIOS_WriteAdrH,W		; W = AddressH - high(adresseMax)-1
	btfsc   STATUS,C				; W < 0 ?
		return				; Sinon, fin
	
	; Ecriture
	BANK2
	MOVR16ToR16 V_BIOS_WriteAdrH, V_BIOS_WriteAdrL, EEADRH, EEADR		;Write address of desired program memory location
	MOVR16ToR16 V_BIOS_RegH, V_BIOS_RegL, EEDATH, EEDATA	;Write value to program at desired memory location

	bsf		STATUS, RP0				;Bank 3
	bsf		EECON1, EEPGD			;Point to Program memory
	bsf		EECON1, WREN			;Enable writes
	bcf		STATUS,C
	btfss	INTCON, GIE				;If interrupts are enabled,
			goto 	FHW_Suite
		bsf		STATUS,C			;Set C=1
		bcf		INTCON, GIE			;and disable interrupts
FHW_Suite
	MOVLF	0x55, EECON2
	MOVLF	0xAA, EECON2
	bsf		EECON1, WR				;Start write operation
	nop								;Two NOPs to allow micro to setup for write
	nop
	btfsc	STATUS,C
		bsf		INTCON, GIE			;Enable interrupts if enabled before
	bcf		EECON1, WREN			;Disable writes
	BANK0
	return


; ////////////////////////////////////////////////////////////////////////////
;                     P R O G R A M M E   P R I N C I P A L
; ////////////////////////////////////////////////////////////////////////////
Principal
			; ---- initialisation PORTS (banque 0 et 1)
;	BANK0
;	clrf	PORTA						; Sorties PORTA à 0
;	clrf	PORTB						; sorties PORTB à 0
;	clrf	PORTC						; sorties PORTC à 0
	BANK1
;	MOVLF	DIRPORTA, TRISA				; Direction PORTA
;	MOVLF	DIRPORTB, TRISB				; Direction PORTB
	MOVLF	DIRPORTC, TRISC				; Direction PORTC
	MOVLF	OPTIONVAL, OPTION_REG		; Registre d'options
;	MOVLF	INTCONVAL, INTCON			; Interruptions				// !!!!!!!!!! Les interruptions sont inactives pour que le bootloader n'occupe pas la zone de gestion des interruptions.

	BANK0
	clrf	V_TRS_Checksum
	MOVLF	B'00000001', V_TRS_RxStep
	call	TRS_OpenComm
	
			; ---- Init BIOS
	bcf		V_BIOSMode

	; ///// Config timer 1 (Attente réception série pour choix mode BOOT) (100ms)
	if CLCK_SPEED==20
		MOVLF	0x00,TMR1H
	else
		MOVLF	0xCC,TMR1H
	endif
	
	MOVLF	0x00,TMR1L
	MOVLF	B'00110001',T1CON			; Source = FOsc/4, Prescaler = 8, Start timer

PP_AttenteChoixMode
	btfsc	PIR1,RCIF					; Réception sur RS232 ?
		goto 	PP_DemarrerModeBIOS		; Oui => Démarrer en mode BIOS
	btfss	PIR1,TMR1IF
		goto PP_AttenteChoixMode
	
PP_DemarrerModeAPPLI
	clrf	T1CON						; Arrête timer
	goto	ADR_Appli

PP_DemarrerModeBIOS
	clrf	T1CON						; Arrête timer
	bsf		V_BIOSMode
	
PP_Attente		; ---- Boucle principale
	btfss	PIR1,RCIF					; Tester si interrupt en cours. LE FLAG NE DOIT PAS ETRE REMIS A 0 (fait par LECTURE DE RCREG)
		goto 	PP_Attente				; non sauter
	call	TRS_RxProg					; oui, traiter interrupt
	btfsc	V_BIOSMode					; Si téléchargement non terminé, continue attente
		goto	PP_Attente
	;Attente
	goto $
	END